package ffffff.exp
{
	import flash.filters.DisplacementMapFilter;	
	import flash.filters.BlurFilter;	
	import flash.display.BitmapDataChannel;	
	import flash.events.Event;	
	import flash.display.Bitmap;	
	import flash.display.BitmapData;	
	import flash.geom.Point;	
	import flash.display.MovieClip;
	
	/**
	 * @author white
	 */
	public class WanderingPixels extends MovieClip {
		
		private const WIDTH:Number = 300;
		private const HEIGHT:Number = 300;
		
		private var output : BitmapData = new BitmapData(WIDTH, HEIGHT,false,0);
		private var map:BitmapData = new BitmapData(WIDTH, HEIGHT);

		private var pixels:Array = [];
		
		private var num:Number = 500;
		
		private var movePoint1:Point = new Point(0, 0);
		private var movePoint2:Point = new Point(0, 0);
		private var origin : Point = new Point(0, 0);
		private var blur : BlurFilter;

		public function WanderingPixels() {
			
			for(var i:Number = 0;i<num;i++)
			{
				var p:Object = {x:Math.random() * WIDTH, y:Math.random() * HEIGHT, speed:Math.random()*25 +5};
				pixels.push(p);
			}
			
			addChild(new Bitmap(output));
			
			blur = new BlurFilter(3,3,3);
			
			addEventListener(Event.ENTER_FRAME, loop);
			loop();
		}
		
		private function loop(event : Event = null) : void {
			map.perlinNoise(50, 50, 5, 6, true, true, BitmapDataChannel.RED | BitmapDataChannel.BLUE,false, [movePoint1,movePoint2,movePoint1,movePoint2]);
			movePoint1.offset( .5, .1);
			movePoint2.offset(.2, -.5);

			var displace : DisplacementMapFilter = new DisplacementMapFilter(map,origin,BitmapDataChannel.RED, BitmapDataChannel.BLUE,-3,-3);
			output.applyFilter(output, output.rect, origin, displace);
			
			for(var i:Number = 0; i<num; i++)
			{
				var p:Object = pixels[i];
				var c:int = map.getPixel(p.x, p.y);
				var red:Number = Number("0x" + c.toString(16).substr(0,2))-128 + Math.random()*6-3;
				var blue:Number = Number("0x" + c.toString(16).substr(4,2))-128 + Math.random()*6-3;
				
				p.x += red/p.speed;
				p.y += blue/p.speed;

				if(p.x >WIDTH) p.x -= WIDTH ;
				if(p.x<0) p.x += WIDTH ;
				if(p.y > HEIGHT) p.y -= HEIGHT ;
				if(p.y <0) p.y += HEIGHT ;
				
				output.setPixel(p.x, p.y, 0x66FF00);
			}
		}
	}
}