package {
	import flash.display.Graphics;
	import flash.display.Sprite;
	import flash.display.StageScaleMode;
	import flash.events.Event;

	[
		SWF( backgroundColor='0xFFFFFF', frameRate='21', width='500', height='500' )
	]
	public class abstraction extends Sprite
	{
		private var mc:Sprite = new Sprite();
		
		private var circles:Array;
		
		private var nums:Number = 100;
		
		private var minX:Number = 0;
		private var maxX:Number = 500;
		private var minY:Number = 0;
		private var maxY:Number = 500;
		
		private var minR:Number = 10;
		private var maxR:Number = 100;
		
		private var startRPC:Number = .8;
		private var rPC:Number = .997;
		
		public function abstraction()
		{
			
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.showDefaultContextMenu = false;
			
			addChild(mc);

			circles = new Array();	
			for(var i:Number = 0; i<nums;i++) {
				
				var x:Number = maxX*Math.random();
				var y:Number = maxY*Math.random();
				
				var r:Number = Math.random() * ( Math.random()>startRPC ? maxR : minR);
				
				var nx:Number = Math.random()*maxX;
				var ny:Number = Math.random()*maxY;
				
				var nr:Number = Math.random() * ( Math.random()>startRPC ? maxR : minR);
				circles.push({x:x, y:y, r:r, nx:nx, ny:ny, nr:nr });
			}
			
			addEventListener(Event.ENTER_FRAME,onEnterFrameListener);
		}
		
		private function onEnterFrameListener(evt:Event):void {
			
			
			var gr:Graphics = mc.graphics;
			
			gr.clear();
			gr.lineStyle(1,0,1);
			gr.beginFill(0,1);
				
			for(var i:Number = 0; i<nums;i++) {
				
				var x:Number = circles[i].x;
				var y:Number = circles[i].y;
				
				var r:Number = circles[i].r;
				
				var nx:Number = circles[i].nx;
				var ny:Number = circles[i].ny;
				
				var nr:Number = circles[i].nr;
				
				x += (nx-x)/100;
				y += (ny-y)/100;
				r += (nr-r)/100;
				

				gr.drawCircle(x,y, r);
				
				circles[i].x = x;
				circles[i].y = y;
				circles[i].r = r;
				
				
				if(Math.abs(nx-x)<10) {
					nx = Math.random()*maxX;
					circles[i].nx = nx;
				}
				if(Math.abs(ny-y)<10) {
					ny = Math.random()*maxY;
					circles[i].ny = ny;
				}
				
				if(Math.abs(nr-r)<10) {
					nr = Math.random()*( Math.random()>rPC ? maxR: minR);
					circles[i].nr = nr;
				}
				
			}
			gr.endFill();
		}
	}
}